;+
;
; NAME:
;	HXISDEFAULTS
;
; PURPOSE:
;	Resets values need for processing of new files.
;
; CATEGORY:
;	HXIS display
;
; CATEGORY:
;	HXIS display
;
; CALLING SEQUENCE:
;	HXISDEFAULTS
;
; CALLED BY:
;  	HXISREAD
; 
; CALLS TO:
;       none 
;
; INPUTS: 
;       none explicit, only through commons
;
; OPTIONAL INPUTS:
;	none
;
; OUTPUTS:
;       none explicit, only through commons
;
; OPTIONAL OUTPUTS:
;	none
;
; COMMON BLOCKS:
;	hxisdata_info.common
;	hxisgrid.common
;	hxispass.common
;			
; SIDE EFFECTS:
;	none
;
; RESTRICTIONS:
;	none
;
; PROCEDURE:
;	Initial necessary value to befin displaying a new file
;
; MODIFICATION HISTORY:
;	OCT-1990, Paul Hick (ARC)
;	DEC-1992, Elaine Einfalt (HSTX) - converted to widgets
;-


pro hxisdefaults

@hxisdata_info.common
@hxisgrid.common
@hxispass.common


 INFO.YXRAT = 1.18

 info.silent=1					; don't bother user
 widget_control, pass_inter, set_value='OFF'

 info.grid=1					; grid turned on
 oldgrid = def_grid				; default grid spacing index
 widget_control, pass_grid, set_value=grid_type(oldgrid)
 info.offset = 1			        ; use offset pointing values

 info.hard=0					; hardcopy turned off
 info.colo=0					; B/W hardcopy


 info.BOT_IMG=0   & info.TOP_IMG=0		; first and last image 
 info.DOY=fix(0)				; Start DOY
 info.FRST_BND=1  & info.LAST_BND=6		; Lowest/highest energy band

 info.FRST_IMG=0   &   info.LAST_IMG=0		; First and last image used 
				           	;   in the duration
 info.duration = info.def_dur			; default duration


 ; Type of contour plot : 0=count rate, 1=temperature, 2=emission measure, 
 ;			  3 = k*temp*emis (-1 has a special meaning, see CPLOT)
 ; info.BTYP=intarr(6)-2	
 info.BTYP=intarr(6)	

 ; Images in CPLOT display count rates for energy bands BLOW through BUP;
 ;  temperatures/emission measure based on ratio BUP/BLOW)
 
 ; info.BLOW=intarr(6)  &  info.BUP=intarr(6) ; Low/high energy bands (SELECT)
 info.BLOW=indgen(6)+1  &  info.BUP=indgen(6)+1 ; Low/high energy bands (SELECT)


 for i = 0,5 do begin
  widget_control, pass_img_typ(i),  set_value='Intensity' 
  widget_control, pass_img_math(i), set_value='Bands Summed'
  widget_control, pass_img_band(i), set_value = strtrim(info.blow(i),2) +$
			'  to  ' + strtrim(info.bup(i),2) 
 endfor

 info.TIME=double(0.)		; Time of the displayed image
 info.SUM=0			; Accumulation time (0.125 sec units)

 ; S/C yaw,pitch (arcsec; S/E is pos), roll (deg)
 info.YAW=0. &  info.PITCH=0. & info.ROLL=0.  	

; Center fov yaw, pitch (arcsec; W/N is positive)
 info.XP=0.  &  info.YP=0.

; 
; Clear out the HXIS pointing values from last data file in case not set
;
; widget_control, pass_hpitch_id, set_value=' 0000.0'
; widget_control, pass_hyaw_id,   set_value=' 0000.0'

;
; Switches and reset widget buttons
;

 info.IMGTV=byte(1)			   ; 0=Contour plots,1=color images
 widget_control, pass_disp_lab, set_value='Image mapping (cplot)'
 

 info.MODE=bytarr(3)			   ; Recalculate everything.
					   ; Status of image/time series 
			                   ;       0=Calculation incomplete; 
				           ;	   1=Calculation complete
					   ; MODE(0) : contour plot status 
					   ;		(CALC_IMG, CPLOT)
					   ; MODE(1) : status of time series
			       		   ;		 for whole area (TPLOT)
					   ; MODE(2) : status of time series 
					   ;		for individual pixels 
					   ;		(XPLOT)


 info.LIFE=byte(0)			   ; Status of lifetime function 
				           ;	(0=Not available/1=Available)

 info.cplot_up=0		  ; Current graphics screen does not yet
				  ; display images

 info.conman=0			  ; 0=don't/1=do (ask for new contour levels)


return
end